[Wien] Wien and batch system

[Peter Blaha]

Hi,

In my understanding there is no need to change anything in the code. All you 
have to write, is a small "script" which is submitted to your batch queuing 
system (and proper configuration of the details of the "mpirun" command during 
siteconfig (or $WIENROOT/parallel_options") like:

setenv WIEN_MPIRUN "/opt/local/mvapich-0.9.8-intel/bin/mpirun -np _NP_ 
-hostfile _HOSTS_ _EXEC_"

The "script" needs to write a .machines file on the fly, using the information 
  on which hosts it is allowed to run from the queuing system. This info is 
usually set in some environment variables and one has access to them. I don't 
know how these variables are named in your case, but you may find some examples 
on our "faq"-page at www.wien2k.at, and I list also a script which I use on the 
loadleveler on our Intel-Xeon-cluster.

Regards
----------------------------------------------------------
#!/bin/csh -f
# @ job_type = parallel
# @ class = large
# @ input = /dev/null
# @ output = $(Executable).$(Cluster).$(Process).out
# @ error = $(Executable).$(Cluster).$(Process).err
# @ notify_user = pblaha at susi.theochem.tuwien.ac.at
# @ notification = always
# @ node_usage = not_shared
# @ initialdir = ~/lapw/nanomesh/pt_nanomesh_9x10
# @ tasks_per_node = 2
# @ node = 32
# @ queue

#setenv SCRATCH /scratch
setenv OMP_NUM_THREADS 1
set mpijob=64

limit coredumpsize 0

echo -n 'running in '
pwd
echo nodes for this job: $LOADL_PROCESSOR_LIST

set proclist=`echo $LOADL_PROCESSOR_LIST`
set nproc=$#proclist
echo number of processors: $nproc

# creating a .machines file on the fly
#--------------------------------------------------------------
echo '#' > .machines

# example for an MPI parallel lapw0
echo -n 'lapw0:' >> .machines
set i=1
while ($i <= $nproc )
#echo -n "$LOADL_PROCESSOR_LIST[$i]" >>.machines
echo -n "$proclist[$i] " >>.machines
@ i = $i + 1
end
echo ' ' >>.machines

#example for k-point and mpi parallel lapw1/2
set i=1
while ($i <= $nproc )
echo -n '1:' >>.machines
@ i1 = $i + $mpijob
@ i2 = $i1 - 1
echo $proclist[$i-$i2] >>.machines
set i=$i1
end
echo 'granularity:1' >>.machines
echo 'extrafine:1' >>.machines
echo 'lapw2_vector_split:1 ' >>.machines

#----------------done -----------------------------------------


min -NI -ex -j "run_lapw -p -I -i 99 -fc 3 -r 60 -it0 "


Andrey Sobolev schrieb:
> Dear Wien users,
> 
> We have been successfully using Wien2k for a while already to perform
> energy calculations of FeCr supercells in sequential mode and using
> k-point parallelization. Recently I tried to install the software on
> the cluster with 52*3,2 GHz Xeons64 and Infiniband under Gentoo-r2.
> The finegrained compilation went ok, but there occurred a problem in
> running a test case. The problem is that we have CLEO batch system
> (http://parcon.parallel.ru/cleo-eng.html) installed on the cluster,
> which itself determines the nodes to run a batch job on. The batch
> system uses its own mpirun script, which doesn't understand the
> -machinefile option. Hence, the .machines file becomes useless. But,
> the file is still needed by lapw to run in parallel. The only solution
> to this problem, as I see it, is to rewrite run_lapw and lapwpara
> scripts to fit CLEO standarts. But first I wanted to ask whether some
> of you have already coped with the problem (although I have not found
> any hints either in UG or in mailing list archives - the execution
> types, if I understand them correctly, apply only to serial execution
> and may be set only from within w2web, and all ports but 22 on our
> cluster are blocked by firewall). Any help will be kindly appreciated.
> 
> Thank you in advance,
> Andrey.
> 
> _______________________________________________
> Wien mailing list
> Wien at zeus.theochem.tuwien.ac.at
> http://zeus.theochem.tuwien.ac.at/mailman/listinfo/wien

-- 

                                       P.Blaha
--------------------------------------------------------------------------
Peter BLAHA, Inst.f. Materials Chemistry, TU Vienna, A-1060 Vienna
Phone: +43-1-58801-15671             FAX: +43-1-58801-15698
Email: blaha at theochem.tuwien.ac.at    WWW: http://info.tuwien.ac.at/theochem/
--------------------------------------------------------------------------