[Wien] how to extact...Parabolfit needs small change

[Peter Blaha]

Here is the parabolfit_lapw file attached.

On 11/18/2017 01:37 PM, Lyudmila wrote:
> 18.11.2017 15:21, Lyudmila wrote:
>> Better try and find the place in parabolfit that determines which part
>> of the output should be rewritten in the ZrO2.ene and ZrO2.latparam. I
>> think that this line should be changed somehow:
>>   grepline :lat '*mon*.scf' 1 -s| cut -c27->$file.latparam
> I have looked through this: the file latparam contains all 3 angles, and
> eosfit6 in a 4-d case takes only one angle (the first one, maybe, that
> is, the forth column).
> So two variants:
> 1) to move the column of changing angles to a proper place.
> That is, you are doing parabolfit, than change columns in the file
> latparam, and do 'x eosfit6'
> 2) you are doing parabolfit, than do 'x eosfit6' and answer that you
> have 6 dimensions - and it will consider 6 columns, in the output you'll
> see much more variables.
>
> By the way, my new version of parabolfit has a misfit: version 3 (abc
> change) looks like
>       grepline :ene "*abc*$scf" 1 -s| cut -c40- >$file.ene
>       grepline :lat "*abc*$scf" 1 -s| cut -c27->$file.latparam
> And program does not have $scf here. I think it should be changed to:
>       grepline :ene "*abc*scf" 1 -s| cut -c40- >$file.ene
>       grepline :lat "*abc*scf" 1 -s| cut -c27->$file.latparam
>
> Best wishes,
> Lyudmila Dobysheva
>
> _______________________________________________
> Wien mailing list
> Wien at zeus.theochem.tuwien.ac.at
> http://zeus.theochem.tuwien.ac.at/mailman/listinfo/wien
> SEARCH the MAILING-LIST at:
> http://www.mail-archive.com/wien@zeus.theochem.tuwien.ac.at/index.html

-- 

                                       P.Blaha
--------------------------------------------------------------------------
Peter BLAHA, Inst.f. Materials Chemistry, TU Vienna, A-1060 Vienna
Phone: +43-1-58801-165300             FAX: +43-1-58801-165982
Email: blaha at theochem.tuwien.ac.at    WIEN2k: http://www.wien2k.at
WWW:   http://www.imc.tuwien.ac.at/TC_Blaha
--------------------------------------------------------------------------
-------------- next part --------------
#!/bin/csh -f

set file    = `pwd`
set file    = $file:t           #tail of file-names
unset help
unset type
unset scf
set angle

while ($#argv)
  switch ($1)
  case -h:
    set help
    shift; breaksw
  case -t:
    shift
    set type = $1
    shift; breaksw
  case -p:
#    shift
    set terminal = png
    shift; breaksw
  case -f:
    shift; set file = $1
    shift; breaksw
  case -scf:
    shift; set scf = $1
    shift; breaksw
  case -a:
    set angle = a
    shift; breaksw
  case -b:
    set angle = b
    shift; breaksw
  case -g:
    set angle = g
    shift; breaksw
  default:
    shift; breaksw
  endsw
end
if ($?help) goto help

if !($?type) then
echo 'enter dimensionality (2-4) of fit:'
    set type=$<
endif

if( $type == '2' ) then
  if( ! $?scf ) set scf='*a+c*.scf'
  grepline :ene "$scf" 1 -s| cut -c40- >$file.ene              
  grepline :lat "$scf" 1 -s| cut -c36->$file.latparam          
else if( $type == '3' ) then
  if( ! $?scf ) set scf='*abc*.scf'
  grepline :ene "$scf" 1 -s| cut -c40- >$file.ene
  grepline :lat "$scf" 1 -s| cut -c27->$file.latparam
else if( $type == '4' ) then
  if( ! $?scf ) set scf='*mon*.scf'
  grepline :ene "$scf" 1 -s| cut -c40- >$file.ene              
  grepline :lat "$scf" 1 -s| cut -c27->$file.latparam          
  if($angle == 'b') then
  grepline :lat "$scf" 1 -s| cut -c27-57,67-73->$file.latparam          
  endif
  if($angle == 'g') then
  grepline :lat "$scf" 1 -s| cut -c27-57,73->$file.latparam          
  endif 
endif

echo The following scf files were used for analysis: 
foreach i ($scf)
  echo $i
end
echo " "

echo "$file.ene and $file.latparam generated"
echo " "

echo $type | x_lapw eosfit6

exit(0)

help:
cat <<EOF
parabolfit_lapw is an interface for fitting E vs. 2-4-dim lattice parameters  
by a non-linear least squares fit (eosfit6) using PORT routines.
Once you have several scf calculations at different volumes (usually generated
with "optimize.job") it generates the required "$file.ene" and "$file.latparam"

parabolfit_lapw [ -t 2/3/4 ]  [ -f FILEHEAD ] [ -scf '*xxx*.scf' ] [-a/b/g]

-a/b/g allows to specify alpha,beta or gamma in 4D fit.

EOF